home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Micro on the Apple Volume 1 (1981)(Micro Ink)[no boot].zip / Micro on the Apple Volume 1 (1981)(Micro Ink)[no boot].do / SHAPE3.bas < prev    next >
BASIC Source File  |  1996-12-24  |  2KB  |  69 lines
  1. 10  REM  ***************************
  2. 12  REM  *                         *
  3. 14  REM  * HOW TO DO A SHAPE TABLE *
  4. 16  REM  *      JOHN FIGUERAS      *
  5. 17  REM  *                         *
  6. 18  REM  *         SHAPE3          *
  7. 20  REM  *                         *
  8. 22  REM  *   COPYRIGHT (C) 1981    *
  9. 23  REM  *     MICRO INK, INC.     *
  10. 24  REM  *  CHELMSFORD, MA 01824   *
  11. 25  REM  *   ALL RIGHTS RESERVED   *
  12. 26  REM  *                         *
  13. 27  REM  ***************************
  14. 28  REM 
  15. 30  REM  **** DISPLAY SHAPE TABLE ****
  16. 32  REM  LOAD NUMERALS SHAPE FILE
  17. 35  PRINT : PRINT : PRINT "HIT ANY KEY FOR EACH PAGE OF TABLE"
  18. 40 D$ =  CHR$(4): PRINT D$;"NOMON C,I,O"
  19. 50  PRINT D$;"BLOAD NUMERALS,A20000,D2"
  20. 60  REM   SET UP POINTER TO NUMERALS
  21. 70 NHI = 78:NL = 32
  22. 80  REM   GET TABLE FOR DISPLAY
  23. 90  INPUT "SHAPE TABLE NAME ";NAME$
  24. 100  INPUT "STARTING ADDRESS ";ADDR
  25. 110  REM   SET UP POINTER TO SHAPE TABLE
  26. 120 AHI =  INT(ADDR/256):ALO = ADDR -256 *AHI
  27. 130  REM   GET NO. OF SHAPES FOR DISPLAY
  28. 140 NN =  PEEK(ADDR)
  29. 150  REM   INITIALIZE SCREEN
  30. 160  HGR : POKE  -16302,0
  31. 170  HCOLOR= 3: SCALE= 1: ROT= 0
  32. 180  FOR I = 1 TO NN
  33. 190 IMOD = I -36 * INT(I/36)
  34. 200  IF IMOD < >1  THEN 350
  35. 210  GET KEY$
  36. 220  REM  SCLEAR SCREEN AND CREATE GRID
  37. 230  REM  GRID WILL HOLD 36 SHAPES
  38. 240  CALL 62450
  39. 250  HPLOT 0,0 TO 269,0 TO 269,180 TO 0,180 TO 0,0
  40. 260  FOR L = 45 TO 269  STEP 45
  41. 270  FOR J = 0 TO 180  STEP 10
  42. 280  HPLOT L,J
  43. 290  NEXT J: NEXT L
  44. 300  FOR L = 30 TO 180  STEP 30
  45. 310  FOR J = 0 TO 269  STEP 45
  46. 320  HPLOT J,L
  47. 330  NEXT J: NEXT L
  48. 340  REM   CALCULATE GRID SQUARE COORDS.
  49. 350  IF IMOD = 0  THEN IMOD = 36
  50. 360 ROW =  INT((IMOD -1)/6)
  51. 370 COL = IMOD -6 *ROW -1
  52. 380 C1 =  INT(I/100)
  53. 390 C2 = I -100 *C1
  54. 400 C2 =  INT(C2/10)
  55. 410 C3 = I -10 * INT(I/10)
  56. 420  POKE 232,NLO: POKE 233,NHI
  57. 430 C1 = C1 +2:C2 = C2 +2:C3 = C3 +2
  58. 440  IF C1 = 2  THEN 460
  59. 450  DRAW C1 AT 45 *COL +5,30 *ROW +7
  60. 460  IF C2 = 2  AND C1 = 2  THEN 480
  61. 470  DRAW C2 AT 45 *COL +10,30 *ROW +7
  62. 480  DRAW C3 AT 45 *COL +15,30 *ROW +7
  63. 490  REM    NOW GET SHAPES
  64. 500  POKE 232,ALO: POKE 233,AHI
  65. 510  DRAW I AT 45 *COL +30,30 *ROW +15
  66. 520  NEXT I
  67. 530  GET KEY$
  68. 540  TEXT 
  69. 550  END